mirror of
https://github.com/openglow-org/forgefirm.git
synced 2026-09-27 08:41:13 -07:00
ScottW514
ee25b89799
Pulls in the coarse-pacing fix for parked wait-for-operator states (a machine left in Door or Hold no longer pins ~28% of the core), plus P10's grblHAL CI/tests and the mlockall-root-only change. Fetch-verified. Adds pacing_test.py (dry hold/resume + CPU measurement) and records the diagnosis and bench validation in BRINGUP.
35 lines
1.2 KiB
BlitzBasic
35 lines
1.2 KiB
BlitzBasic
DESCRIPTION = "grblHAL motion controller for the Glowforge factory board"
|
|
HOMEPAGE = "https://github.com/ScottW514/grblHAL-glowforge"
|
|
|
|
LICENSE = "GPL-3.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=3237e48bcef3455c7bea5c0ce16206f6"
|
|
|
|
PV = "0.1.0"
|
|
|
|
# gitsm: the grblHAL core rides as a submodule (ScottW514/core, branch
|
|
# forgefirm = upstream master + the step_us_min buffer fix pending
|
|
# upstream).
|
|
SRC_URI = "gitsm://github.com/ScottW514/grblHAL-glowforge.git;protocol=https;branch=main"
|
|
# Pinned; bump deliberately after pushing grblHAL-glowforge changes.
|
|
SRCREV = "b2cad8d8acc49d0f317550f7c5961b76eae63a70"
|
|
|
|
SRC_URI += "file://grblhal.init"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit cmake update-rc.d
|
|
|
|
INITSCRIPT_NAME = "grblhal"
|
|
# stop 80 < forgectrl's 90: at runlevel 0/6 the controller goes down
|
|
# BEFORE the daemon that carries the cooling engine, fire gates, and
|
|
# broker - never the other way around.
|
|
INITSCRIPT_PARAMS = "start 92 2 3 4 5 . stop 80 0 1 6 ."
|
|
|
|
do_install:append() {
|
|
install -d ${D}${sysconfdir}/init.d
|
|
install -m 0755 ${WORKDIR}/grblhal.init ${D}${sysconfdir}/init.d/grblhal
|
|
}
|
|
|
|
# The controller streams into /dev/glowforge (glowforge.ko) at runtime.
|
|
RRECOMMENDS:${PN} = "kernel-module-glowforge"
|